Terraform و OpenTofu

پرووایدر از رجیستری خود ما روی ibel.ai نصب می‌شود، چون رجیستری‌های عمومی از داخل ایران قابل اتکا نیستند. با Terraform نسخهٔ ۱.۵ به بعد و OpenTofu نسخهٔ ۱.۶ به بعد کار می‌کند.

terraform {
  required_providers {
    cloudhost = {
      source = "ibel.ai/cloudhost/cloudhost"
    }
  }
}

provider "cloudhost" {}

یک کلید API ایجاد کنید (داشبورد، تنظیمات، کلیدهای API؛ یا cloudhost keys create) و در محیط به پرووایدر بدهید. بدون آن، پرووایدر کلیدی را که cloudhost login ذخیره کرده به کار می‌برد.

export CLOUDHOST_API_KEY=chk_live_…
terraform init
terraform plan

هر منبع یک data source هم‌نام دارد که چیزی را که از قبل هست می‌خواند، و هر منبع را می‌شود با terraform import به state آورد.

resource "cloudhost_project" "api" {
  name = "shop-api"
  kind = "function"
}

resource "cloudhost_database" "shop" {
  name = "shop"
}

resource "cloudhost_cache" "sessions" {
  name          = "shop-sessions"
  max_memory_mb = 128
}

resource "cloudhost_environment_variable" "database_url" {
  project = cloudhost_project.api.name
  key     = "DATABASE_URL"
  value   = cloudhost_database.shop.connection_string
  type    = "sensitive"
}

resource "cloudhost_domain" "api" {
  project = cloudhost_project.api.name
  name    = "api.example.ir"
}

resource "cloudhost_alert" "errors" {
  project   = cloudhost_project.api.name
  metric    = "error_rate"
  op        = ">"
  threshold = 0.05
  channels  = { email = true }
}

resource "cloudhost_webhook" "deploys" {
  url     = "https://hooks.example.ir/deploys"
  events  = ["deployment.ready", "deployment.failed"]
  project = cloudhost_project.api.name
}

output "dns_records" {
  value = [for r in cloudhost_domain.api.records : "${r.host} ${r.type} ${r.value}"]
}

کد را همچنان با cloudhost deploy یا git push منتشر کنید؛ Terraform چیزی را ایجاد می‌کند که کد روی آن اجرا می‌شود. متغیر محیطی جدید بی‌درنگ اعمال می‌شود و استقرار جدید لازم ندارد.

رمز دیتابیس، توکن کش، secret ذخیره‌سازی و secret امضای وب‌هوک را API فقط یک بار، هنگام ایجاد، نشان می‌دهد. پرووایدر آن‌ها را در state نگه می‌دارد تا منابع دیگر به کارشان ببرند؛ state را جایی نگه دارید که فقط تیم شما بخواند، و رمزنگاری‌شده.

• بعد از import این مقدارها معلوم نیستند. برای دیتابیس، password_rotation را عوض کنید تا رمز جدید بگیرید.
• مقدار متغیر sensitive هرگز برنمی‌گردد؛ Terraform همان مقدار پیکربندی را نگه می‌دارد. مقدار plain خوانده می‌شود و تغییرش بیرون از Terraform در plan دیده می‌شود.

• دیتابیس، کش و باکت درجا تغییر نمی‌کنند: max_memory_mb دیگر یعنی کش جدید و خالی. plan را بخوانید.
• دیتابیس، کش یا باکتی که نسخهٔ زنده‌ای به آن متصل است حذف نمی‌شود؛ باکتی که آبجکت دارد هم. اول اتصال را بردارید (بدون آن مستقر کنید) یا باکت را خالی کنید.
• هشدار به‌روزرسانی ندارد: قاعدهٔ عوض‌شده از نو ایجاد می‌شود.
• عضو تیم با دعوت می‌آید؛ تا دعوت را نپذیرفته، status برابر invited است. تغییر نقش یک دعوت، آن را پس می‌گیرد و دوباره می‌فرستد.
• پروژهٔ وب‌هوک درجا عوض نمی‌شود: وب‌هوک و secret جدید.